mirror of https://lore.kernel.org/lkml/
 help / color / mirror / Atom feed
From: Nicolas Palix <npalix@diku.dk>
To: Andrew Morton <akpm@linux-foundation.org>,
	Joe Perches <joe@perches.com>,
	"David S. Miller" <davem@davemloft.net>,
	Michal Marek <mmarek@suse.cz>, Sam Ravnborg <sam@ravnborg.org>,
	Julia Lawall <julia@diku.dk>,
	Gilles Muller <Gilles.Muller@lip6.fr>,
	Nicolas Palix <npalix@diku.dk>,
	linux-kernel@vger.kernel.org, linux-kbuild@vger.kernel.org,
	cocci@diku.dk
Subject: [PATCH 3/4] Add scripts/smpl/kzalloc-simple.cocci
Date: Mon, 26 Apr 2010 23:11:18 +0200	[thread overview]
Message-ID: <1272316279-12042-4-git-send-email-npalix@diku.dk> (raw)
In-Reply-To: <1272316279-12042-1-git-send-email-npalix@diku.dk>

This semantic patch replaces a pair of calls to kmalloc and memset
by a single call to kzalloc.

It only looks for simple cases to improve the confidence.

Signed-off-by: Nicolas Palix <npalix@diku.dk>
---
 scripts/smpl/kzalloc-simple.cocci |   88 +++++++++++++++++++++++++++++++++++++
 1 files changed, 88 insertions(+), 0 deletions(-)
 create mode 100644 scripts/smpl/kzalloc-simple.cocci

diff --git a/scripts/smpl/kzalloc-simple.cocci b/scripts/smpl/kzalloc-simple.cocci
new file mode 100644
index 0000000..d4e1b25
--- /dev/null
+++ b/scripts/smpl/kzalloc-simple.cocci
@@ -0,0 +1,88 @@
+///
+/// kzalloc should be used rather than kmalloc followed by memset 0
+///
+/// The semantic patch that makes this change is available
+/// in THISFILE.
+///
+/// More information about semantic patching is available at
+/// http://coccinelle.lip6.fr/
+///
+// Confidence: High
+// Copyright: (C) 2009-2010 Gilles Muller, Julia Lawall, Nicolas Palix, EMN, DIKU.  GPLv2.
+// URL: http://coccinelle.lip6.fr/rules/kzalloc.html
+// Options: -no_includes -include_headers
+//
+// Keywords: kmalloc, kzalloc
+// Version min: < 12 kmalloc
+// Version min:   14 kzalloc
+// Version max: *
+//
+
+virtual context
+virtual patch
+virtual org
+virtual report
+
+//----------------------------------------------------------
+//  For context mode
+//----------------------------------------------------------
+
+@depends on context@
+type T, T2;
+expression x;
+expression E1,E2;
+statement S;
+@@
+
+* x = (T)kmalloc(E1,E2);
+  if ((x==NULL) || ...) S
+* memset((T2)x,0,E1);
+
+//----------------------------------------------------------
+//  For patch mode
+//----------------------------------------------------------
+
+@depends on patch@
+type T, T2;
+expression x;
+expression E1,E2;
+statement S;
+@@
+
+- x = (T)kmalloc(E1,E2);
++ x = kzalloc(E1,E2);
+  if ((x==NULL) || ...) S
+- memset((T2)x,0,E1);
+
+//----------------------------------------------------------
+//  For org mode
+//----------------------------------------------------------
+
+@r depends on org || report@
+type T, T2;
+expression x;
+expression E1,E2;
+statement S;
+position p;
+@@
+
+ x = (T)kmalloc@p(E1,E2);
+ if ((x==NULL) || ...) S
+ memset((T2)x,0,E1);
+
+@script:python depends on org@
+p << r.p;
+x << r.x;
+@@
+
+msg="%s" % (x)
+msg_safe=msg.replace("[","@(").replace("]",")")
+coccilib.org.print_todo(p[0], msg_safe)
+
+@script:python depends on report@
+p << r.p;
+x << r.x;
+@@
+
+msg="WARNING: kzalloc should be used for %s, instead of kmalloc/memset" % (x)
+coccilib.report.print_report(p[0], msg_safe)
-- 
1.6.3.3


  parent reply	other threads:[~2010-04-26 21:12 UTC|newest]

Thread overview: 17+ messages / expand[flat|nested]  mbox.gz  Atom feed  top
2010-04-26 21:11 [PATCH 0/4] Add a Coccinelle front-end script Nicolas Palix
2010-04-26 21:11 ` [PATCH 1/4] Add targets to use the Coccinelle checker Nicolas Palix
2010-04-26 21:37   ` Joe Perches
2010-04-26 22:20     ` Nicolas Palix
2010-04-26 22:23       ` Randy Dunlap
2010-04-29 17:01         ` Roland Dreier
2010-04-30 21:07           ` Randy Dunlap
2010-04-27 12:40       ` Michal Marek
2010-04-27 13:01       ` Michal Marek
2010-04-27 12:53   ` Wolfram Sang
2010-04-27 20:24   ` Sam Ravnborg
2010-04-27 20:28     ` Sam Ravnborg
2010-04-26 21:11 ` [PATCH 2/4] Add scripts/smpl/drop_kmalloc_cast.cocci Nicolas Palix
2010-04-26 21:11 ` Nicolas Palix [this message]
2010-04-26 21:11 ` [PATCH 4/4] Add scripts/smpl/resource_size.cocci Nicolas Palix
2010-04-27 12:50 ` [PATCH 0/4] Add a Coccinelle front-end script Wolfram Sang
2010-04-27 12:53   ` Julia Lawall

Reply instructions:

You may reply publicly to this message via plain-text email
using any one of the following methods:

* Save the following mbox file, import it into your mail client,
  and reply-to-all from there: mbox

  Avoid top-posting and favor interleaved quoting:
  https://en.wikipedia.org/wiki/Posting_style#Interleaved_style

* Reply using the --to, --cc, and --in-reply-to
  switches of git-send-email(1):

  git send-email \
    --in-reply-to=1272316279-12042-4-git-send-email-npalix@diku.dk \
    --to=npalix@diku.dk \
    --cc=Gilles.Muller@lip6.fr \
    --cc=akpm@linux-foundation.org \
    --cc=cocci@diku.dk \
    --cc=davem@davemloft.net \
    --cc=joe@perches.com \
    --cc=julia@diku.dk \
    --cc=linux-kbuild@vger.kernel.org \
    --cc=linux-kernel@vger.kernel.org \
    --cc=mmarek@suse.cz \
    --cc=sam@ravnborg.org \
    /path/to/YOUR_REPLY

  https://kernel.org/pub/software/scm/git/docs/git-send-email.html

* If your mail client supports setting the In-Reply-To header
  via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox

all inboxes | Powered by JetHome®