/* __KERNEL__ *//* _I386_PAGE_H *//* ld script to make i386 Linux kernel
 * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>;
 */
OUTPUT_FORMAT("elf32-i386", "elf32-i386", "elf32-i386")
OUTPUT_ARCH(i386)
ENTRY(_start)
SECTIONS
{
  . = __PAGE_OFFSET + 0x100000;
  .text.startup : {
	BYTE(0xEA) /* jmp far */


	LONG(startup_32 - __PAGE_OFFSET)


	SHORT(0x10 )
	}

  . = ALIGN(32);
  _data = .;
  .data : {			/* Data */
	*(.data)
	CONSTRUCTORS
	}

  . = ALIGN(32);
  .data.cacheline_aligned : { *(.data.cacheline_aligned) }

  . = ALIGN(8192);
  .data.init_task : { *(.data.init_task) }

  . = ALIGN(4096);
  .data.page_aligned : { *(.data.swapper_pg_dir) }

  _edata = .;			/* End of data section */

  __bss_start = .;		/* BSS */
  .bss : {
	*(.bss)
	LONG(0)
	} 
  __bss_end = . ;

  . = ALIGN(4096);		/* Init code and data */
  __init_begin = .;

  .data.init : {
	*(.data.pg0)
	*(.data.pg1)
	*(.data.pg2)
	*(.data.init)
	}
  . = ALIGN(16);
  __setup_start = .;
  .setup.init : { *(.setup.init) }
  __setup_end = .;
  __initcall_start = .;
  .initcall.init : { *(.initcall.init) }
  __initcall_end = .;


  .text.init : { *(.text.init) }
  . = ALIGN(4096);
  __init_end = .;
  _text = .;			/* Text and read-only data */
  .text : {


	*(.text)
	*(.fixup)
	*(.gnu.warning)
	} = 0x9090

  _etext = .;			/* End of text section */
  . = ALIGN(4096);



  .rodata.page_aligned : {
	*(.data.empty_zero_page)
	*(.data.idt)
	}
  .rodata : { *(.rodata) *(.rodata.*) }
  .kstrtab : { *(.kstrtab) }

  . = ALIGN(16);		/* Exception table */
  __start___ex_table = .;
  __ex_table : { *(__ex_table) }
  __stop___ex_table = .;

  __start___ksymtab = .;	/* Kernel symbol table */
  __ksymtab : { *(__ksymtab) }
  __stop___ksymtab = .;


  _end = .;


  /* Sections to be discarded */
  /DISCARD/ : {
	*(.text.exit)
	*(.data.exit)
	*(.exitcall.exit)
	}

  /* Stabs debugging sections.  */
  .stab 0 : { *(.stab) }
  .stabstr 0 : { *(.stabstr) }
  .stab.excl 0 : { *(.stab.excl) }
  .stab.exclstr 0 : { *(.stab.exclstr) }
  .stab.index 0 : { *(.stab.index) }
  .stab.indexstr 0 : { *(.stab.indexstr) }
  .comment 0 : { *(.comment) }
}