Re: [PATCH v3 3/4] openrisc: Add unit tests for KProbes on branch instructions

[Stafford Horne <shorne@gmail.com>]

On Tue, Oct 27, 2026 at 01:42:39AM +0530, Sahil Siddiq wrote:
> Tests already exist lib/tests to verify the generic functionality of
> KProbes. Add unit tests to verify that KProbes work on instructions
> that require simulation in the OpenRISC ISA, and that the corresponding
> delay slots are handled correctly.
> 
> Signed-off-by: Sahil Siddiq <sahilcdq0@gmail.com>
> ---
> Changes v2 -> v3:
> - arch/openrisc/kernel/tests/test_kprobes_asm.S:
>   - (test_kprobes_*): Set value in r11 register to 0 prior to running tests
>   - (test_kprobes_adrp):
>     Place function at page-aligned address
>     Use PAGE_SIZE macro instead of magic number
>     Move value in r13 to r11 before exiting
> 
> Changes v1 -> v2: New commit
> 
>  arch/openrisc/Kconfig.debug                   |  30 +++-
>  arch/openrisc/kernel/Makefile                 |   1 +
>  arch/openrisc/kernel/tests/Makefile           |   3 +
>  arch/openrisc/kernel/tests/test_kprobes.c     |  59 +++++++
>  arch/openrisc/kernel/tests/test_kprobes.h     |  24 +++
>  arch/openrisc/kernel/tests/test_kprobes_asm.S | 157 ++++++++++++++++++
>  6 files changed, 273 insertions(+), 1 deletion(-)
>  create mode 100644 arch/openrisc/kernel/tests/Makefile
>  create mode 100644 arch/openrisc/kernel/tests/test_kprobes.c
>  create mode 100644 arch/openrisc/kernel/tests/test_kprobes.h
>  create mode 100644 arch/openrisc/kernel/tests/test_kprobes_asm.S
> 
> diff --git a/arch/openrisc/Kconfig.debug b/arch/openrisc/Kconfig.debug
> index 295942fe3fd5..54110f3a111f 100644
> --- a/arch/openrisc/Kconfig.debug
> +++ b/arch/openrisc/Kconfig.debug
> @@ -1,2 +1,30 @@
>  # SPDX-License-Identifier: GPL-2.0-only
> -# dummy file, do not delete
> +menu "openrisc Testing"
> +
> +menuconfig RUNTIME_KERNEL_TESTING_MENU
> +    bool "openrisc kernel runtime testing"
> +    default y
> +    help
> +      Enable openrisc kernel runtime testing. With this option, one can
> +      build and run tests to verify the correctness of relevant components
> +      in the kernel at runtime.
> +
> +if RUNTIME_KERNEL_TESTING_MENU
> +
> +config OR_KPROBES_KUNIT
> +    tristate "KUnit test for kprobes on openrisc"
> +    depends on KUNIT
> +    depends on KPROBES
> +    default KUNIT_ALL_TESTS
> +    help
> +      Enable testing of KProbes in OpenRISC for instructions that
> +      require simulation. When further changes related to probes or
> +      tracing are added to OpenRISC's port, these tests can help
> +      verify that instruction simulation and processing of delay slots
> +      continue to work as expected.
> +
> +      If unsure, say N
> +
> +endif # RUNTIME_KERNEL_TESTING_MENU
> +
> +endmenu # "openrisc Testing"
> diff --git a/arch/openrisc/kernel/Makefile b/arch/openrisc/kernel/Makefile
> index 2ac824867963..0c1cade09e0c 100644
> --- a/arch/openrisc/kernel/Makefile
> +++ b/arch/openrisc/kernel/Makefile
> @@ -15,6 +15,7 @@ obj-$(CONFIG_STACKTRACE)	+= stacktrace.o
>  obj-$(CONFIG_MODULES)		+= module.o
>  obj-$(CONFIG_OF)		+= prom.o
>  obj-$(CONFIG_KPROBES)		+= kprobes.o
> +obj-$(CONFIG_OR_KPROBES_KUNIT)	+= tests/
>  obj-y	+= patching.o
>  
>  clean:
> diff --git a/arch/openrisc/kernel/tests/Makefile b/arch/openrisc/kernel/tests/Makefile
> new file mode 100644
> index 000000000000..9e9693fd3550
> --- /dev/null
> +++ b/arch/openrisc/kernel/tests/Makefile
> @@ -0,0 +1,3 @@
> +obj-$(CONFIG_OR_KPROBES_KUNIT)	+= openrisc_test_kprobes.o
> +
> +openrisc_test_kprobes-objs := test_kprobes.o test_kprobes_asm.o
> diff --git a/arch/openrisc/kernel/tests/test_kprobes.c b/arch/openrisc/kernel/tests/test_kprobes.c
> new file mode 100644
> index 000000000000..a41bdec662e1
> --- /dev/null
> +++ b/arch/openrisc/kernel/tests/test_kprobes.c
> @@ -0,0 +1,59 @@
> +// SPDX-License-Identifier: GPL-2.0-or-later
> +/*
> + * KProbe unit tests for OpenRISC
> + *
> + * Unit tests borrowed liberally from similar work of RISC-V. All
> + * original copyrights apply as per the original source declaration.
> + */
> +
> +// #include <linux/kernel.h>
> +#include <linux/kprobes.h>
> +#include <kunit/test.h>
> +#include "test_kprobes.h"
> +
> +static void test_kprobe_openrisc(struct kunit *test)
> +{
> +	unsigned int num_kprobe = 0;
> +	unsigned long (*func)(void);
> +	struct kprobe *kp;
> +	int i;
> +
> +	while (test_kprobes_addresses[num_kprobe])
> +		num_kprobe++;
> +
> +	kp = kcalloc(num_kprobe, sizeof(struct kprobe), GFP_KERNEL);
> +	KUNIT_EXPECT_TRUE(test, kp);
> +	if (!kp)
> +		return;
> +
> +	for (i = 0; i < num_kprobe; ++i) {
> +		kp[i].addr = test_kprobes_addresses[i];
> +		KUNIT_EXPECT_EQ(test, 0, register_kprobe(&kp[i]));
> +	}
> +
> +	for (i = 0;; ++i) {
> +		func = test_kprobes_functions[i];
> +		if (!func)
> +			break;
> +		KUNIT_EXPECT_EQ_MSG(test, KPROBE_TEST_MAGIC, func(), "function %d broken", i);
> +	}
> +
> +	for (i = 0; i < num_kprobe; ++i)
> +		unregister_kprobe(&kp[i]);
> +	kfree(kp);
> +}
> +
> +static struct kunit_case kprobes_testcases[] = {
> +	KUNIT_CASE(test_kprobe_openrisc),
> +	{}
> +};
> +
> +static struct kunit_suite kprobes_test_suite = {
> +	.name = "kprobes_openrisc",
> +	.test_cases = kprobes_testcases,
> +};
> +
> +kunit_test_suites(&kprobes_test_suite);
> +
> +MODULE_LICENSE("GPL");
> +MODULE_DESCRIPTION("KUnit test for OpenRISC KProbes");
> diff --git a/arch/openrisc/kernel/tests/test_kprobes.h b/arch/openrisc/kernel/tests/test_kprobes.h
> new file mode 100644
> index 000000000000..26c26920d430
> --- /dev/null
> +++ b/arch/openrisc/kernel/tests/test_kprobes.h
> @@ -0,0 +1,24 @@
> +/* SPDX-License-Identifier: GPL-2.0-or-later */
> +/*
> + * Unit tests borrowed liberally from similar work of RISC-V. All
> + * original copyrights apply as per the original source declaration.
> + */
> +
> +#ifndef TEST_KPROBES_H
> +#define TEST_KPROBES_H
> +
> +#define KPROBE_TEST_MAGIC          0xDEADC0DE
> +#define KPROBE_TEST_MAGIC_LOWER    0x0000C0DE
> +#define KPROBE_TEST_MAGIC_UPPER    0x0000DEAD
> +
> +#ifndef __ASSEMBLER__
> +
> +/* array of addresses to install kprobes */
> +extern void *test_kprobes_addresses[];
> +
> +/* array of functions that return KPROBE_TEST_MAGIC */
> +extern unsigned long (*test_kprobes_functions[])(void);
> +
> +#endif /* __ASSEMBLER__ */
> +
> +#endif /* TEST_KPROBES_H */
> diff --git a/arch/openrisc/kernel/tests/test_kprobes_asm.S b/arch/openrisc/kernel/tests/test_kprobes_asm.S
> new file mode 100644
> index 000000000000..bc87a5fb00d5
> --- /dev/null
> +++ b/arch/openrisc/kernel/tests/test_kprobes_asm.S
> @@ -0,0 +1,157 @@
> +/* SPDX-License-Identifier: GPL-2.0-or-later */
> +/*
> + * KProbes unit tests for OpenRISC
> + *
> + * Unit tests borrowed liberally from similar work of RISC-V. All
> + * original copyrights apply as per the original source declaration.
> + */
> +
> +#include <linux/linkage.h>
> +#include <asm/asm.h>
> +#include <asm/page.h>
> +
> +#include "test_kprobes.h"
> +
> +SYM_FUNC_START(test_kprobes_j)
> +test_kprobes_j_addr1:
> +	l.addi	r11,r0,0
> +	l.j	2f
> +	l.nop

Just a tiny comment here about indenting the delay slots.

You could also use the delayslots here, for example:

	l.j	2f
	 l.addi	r11,r0,0

> +1:	l.ori	r13,r13,KPROBE_TEST_MAGIC_LOWER
> +	l.addi	r11,r13,0
> +	l.jr	r9
> +	l.nop
> +2:	l.movhi	r13,KPROBE_TEST_MAGIC_UPPER
> +test_kprobes_j_addr2:
> +	l.j	1b
> +	l.nop
> +SYM_FUNC_END(test_kprobes_j)
> +
> +SYM_FUNC_START(test_kprobes_jal)
> +	l.addi	r11,r0,0
> +	l.addi	r15,r9,0
> +test_kprobes_jal_addr1:
> +	l.jal	2f
> +	l.nop
> +1:	l.movhi	r13,KPROBE_TEST_MAGIC_UPPER
> +	l.jr	r9
> +	l.nop
> +test_kprobes_jal_addr2:
> +2:	l.jal	1b
> +	l.nop
> +	l.ori	r13,r13,KPROBE_TEST_MAGIC_LOWER
> +	l.addi	r11,r13,0
> +	l.addi	r9,r15,0
> +	l.jr	r9
> +	l.nop
> +SYM_FUNC_END(test_kprobes_jal)
> +
> +SYM_FUNC_START(test_kprobes_jr)
> +	l.addi	r11,r0,0
> +	l.movhi	r15,hi(2f)
> +	l.ori	r15,r15,lo(2f)
> +test_kprobes_jr_addr1:
> +	l.jr	r15
> +	l.nop
> +1:	l.ori	r13,r13,KPROBE_TEST_MAGIC_LOWER
> +	l.addi	r11,r13,0
> +	l.jr	r9
> +	l.nop
> +2:	l.movhi	r13,KPROBE_TEST_MAGIC_UPPER
> +	l.movhi	r15,hi(1b)
> +	l.ori	r15,r15,lo(1b)
> +test_kprobes_jr_addr2:
> +	l.jr	r15
> +	l.nop
> +SYM_FUNC_END(test_kprobes_jr)
> +
> +SYM_FUNC_START(test_kprobes_jalr)
> +	l.addi	r11,r0,0
> +	l.addi	r15,r9,0
> +	l.movhi	r17,hi(2f)
> +	l.ori	r17,r17,lo(2f)
> +test_kprobes_jalr_addr1:
> +	l.jalr	r17
> +	l.nop
> +1:	l.movhi	r13,KPROBE_TEST_MAGIC_UPPER
> +	l.jr	r9
> +	l.nop
> +2:	l.movhi	r17,hi(1b)
> +	l.ori	r17,r17,lo(1b)
> +test_kprobes_jalr_addr2:
> +	l.jalr	r17
> +	l.nop
> +	l.ori	r13,r13,KPROBE_TEST_MAGIC_LOWER
> +	l.addi	r11,r13,0
> +	l.addi	r9,r15,0
> +	l.jr	r9
> +	l.nop
> +SYM_FUNC_END(test_kprobes_jalr)
> +
> +SYM_FUNC_START(test_kprobes_branch)
> +	l.addi	r11,r0,0
> +	l.addi	r15,r0,1
> +	l.addi	r17,r0,0
> +	l.sfgts	r15,r17
> +test_kprobes_branch_addr1:
> +	l.bf	2f
> +	l.nop
> +1:	l.ori	r13,r13,KPROBE_TEST_MAGIC_LOWER
> +	l.addi	r11,r13,0
> +	l.jr	r9
> +	l.nop
> +2:	l.movhi	r13,KPROBE_TEST_MAGIC_UPPER
> +	l.sfeq	r15,r17
> +test_kprobes_branch_addr2:
> +	l.bnf	1b
> +	l.nop
> +SYM_FUNC_END(test_kprobes_branch)
> +
> +	.align	PAGE_SIZE
> +SYM_FUNC_START(test_kprobes_adrp)
> +	l.addi	r11,r0,0
> +	l.addi	r13,r0,0
> +	l.addi	r15,r9,0
> +	l.addi	r17,r0,-PAGE_SIZE
> +	l.jal	1f
> +	l.nop
> +1:	l.and	r19,r9,r17
> +test_kprobes_adrp_addr:
> +	l.adrp	r21,0
> +	l.sfeq	r21,r19
> +	l.bnf	2f
> +	l.nop
> +	l.movhi	r13,KPROBE_TEST_MAGIC_UPPER
> +	l.ori	r13,r13,KPROBE_TEST_MAGIC_LOWER
> +	l.addi	r11,r13,0
> +2:	l.addi	r9,r15,0
> +	l.jr	r9
> +	l.nop
> +SYM_FUNC_END(test_kprobes_adrp)
> +
> +    .section .rodata
> +SYM_DATA_START(test_kprobes_addresses)
> +	.word test_kprobes_j_addr1
> +	.word test_kprobes_j_addr2
> +	.word test_kprobes_jal_addr1
> +	.word test_kprobes_jal_addr2
> +	.word test_kprobes_jr_addr1
> +	.word test_kprobes_jr_addr2
> +	.word test_kprobes_jalr_addr1
> +	.word test_kprobes_jalr_addr2
> +	.word test_kprobes_branch_addr1
> +	.word test_kprobes_branch_addr2
> +	.word test_kprobes_adrp_addr
> +	.word 0
> +SYM_DATA_END(test_kprobes_addresses)
> +
> +    .section .rodata
> +SYM_DATA_START(test_kprobes_functions)
> +	.word test_kprobes_j
> +	.word test_kprobes_jal
> +	.word test_kprobes_jr
> +	.word test_kprobes_jalr
> +	.word test_kprobes_branch
> +	.word test_kprobes_adrp
> +	.word 0
> +SYM_DATA_END(test_kprobes_functions)
> -- 
> 2.55.0
>